Backup

Poor man's backup

Option explicit
'Poor man's backup
Const Verbose=True
Dim fso,t
t=Now
Set fso=wscript.CreateObject("Scripting.FileSystemObject")
Traite "c:\","h:\svg_c"
Traite "d:\","h:\svg_d"
Traite "e:\","h:\svg_e"
Set fso=Nothing
If Verbose Then Wscript.Echo "Elapsed : " & cdate(Now-t)

Sub Traite(RepSource,RepDest)
	Dim r,f,S,D,z
	Set r=fso.GetFolder(RepSource)
	If Verbose Then WScript.Echo "Handling Folder " & RepDest
	If Not fso.FolderExists(RepDest) Then fso.CreateFolder(RepDest)
	For each f in r.Files
		S=fso.BuildPath(RepSource,f.name)
		D=fso.BuildPath(RepDest,f.name)
		If fso.FileExists(D) Then
			Set z=fso.GetFile(D)
			If z.Size<>f.Size Or z.DateLastModified<>f.DateLastModified Then
				If Verbose Then Wscript.Echo "Copying " & D
				f.Copy D,True
			End If
			Set z=Nothing
		Else
			If Verbose Then Wscript.Echo "Copying " & D
			On error resume next
			f.Copy D
			If Err.Number<>0 Then Wscript.echo "Error : " & S
			on Error Goto 0
		End If
	Next
	For each f in r.SubFolders
		S=fso.BuildPath(RepSource,f.name)
		D=fso.BuildPath(RepDest,f.name)
		Traite S,D
	Next
	Set r=Nothing
End Sub